# $Id: $
# Maintainer:
# Contributor: Hugo Doria <hugo@archlinux.org>
# Contributor: Aurelien Foret <orelien@chez.com>

pkgname=zsnes
pkgver=1.51
pkgrel=7
pkgdesc="Super Nintendo emulator"
url="http://www.zsnes.com/"
arch=('i686')
license=('GPL')
depends=('gcc-libs' 'sdl' 'libpng>=1.4.0' 'libgl' 'ncurses' 'mesa')
makedepends=('nasm' 'gcc')
source=(http://downloads.sourceforge.net/${pkgname}/zsnes151src.tar.bz2
	zsnes.patch
	zsnes.desktop
	zsnes_icon.png)
md5sums=('7071186bf80632ae88a153239498d8c9'
	'4df831b3d87a35949bcf3fd5547decb1'
	'b100b2aa342c551167d7c5dcdcde9dd4'
	'b5260c02adfc3b7ff725041214b00bfd')

build() {
  cd ${srcdir}/${pkgname}_1_51/
  patch -p1 -i ../zsnes.patch || return 1
  
  cd ${srcdir}/${pkgname}_1_51/src
  ./autogen.sh --prefix=/usr \
    x_libraries=/usr/lib \
    force_arch=i686 \
    --enable-release
  
  make || return 1
  make DESTDIR=${pkgdir} install
  
  # adding --mandir= to autoconf line fails
  install -dm755 ${pkgdir}/usr/share

  install -Dm644 ${srcdir}/zsnes.desktop ${pkgdir}/usr/share/applications/zsnes.desktop
  install -Dm644 ${srcdir}/zsnes_icon.png ${pkgdir}/usr/share/pixmaps/zsnes_icon.png

  mv ${pkgdir}/usr/man ${pkgdir}/usr/share
}