# $Id: PKGBUILD 36474 2011-01-02 19:39:06Z jlichtblau $
# Maintainer: Jaroslav Lichtblau <dragonlord@aur.archlinux.org>

pkgname=fillets-ng
pkgver=1.0.0
pkgrel=1
pkgdesc="A port of the wonderful puzzle game Fish Fillets"
url="http://fillets.sf.net/"
arch=('i686' 'x86_64')
license=('GPL')
depends=('fillets-ng-data' 'lua' 'fribidi' 'gcc-libs' 'libx11' 'sdl_mixer' 'sdl_ttf' 'sdl_image' 'desktop-file-utils')
install=$pkgname.install
changelog=$pkgname.changelog
source=(http://downloads.sourceforge.net/fillets/$pkgname-$pkgver.tar.gz \
        http://fillets.sourceforge.net/img/icon.png \
        $pkgname.desktop)
md5sums=('276bb416d7f8bf9ef0969fd7a3c42d52'
         '746a6f71ba1a6b5a918f04448b3db7eb'
         '803617e630043e49807b380cd28803dc')

build() {
  cd ${srcdir}/$pkgname-$pkgver

  ./configure --prefix=/usr --datadir=/usr/share/$pkgname
  make
}

package() {
  cd ${srcdir}/$pkgname-$pkgver

  make DESTDIR=${pkgdir} install

#.desktop and icon files
  install -D -m644 ${srcdir}/icon.png \
    ${pkgdir}/usr/share/pixmaps/$pkgname.png
  install -D -m644 ${srcdir}/$pkgname.desktop \
    ${pkgdir}/usr/share/applications/$pkgname.desktop

}