#Packager: George Vlahavas <vlahavas~at~gmail~dot~com>

pkgname=unrar
pkgver=6.1.6
pkgrel=1gv
source=("http://www.rarlab.com/rar/unrarsrc-$pkgver.tar.gz" "unrar.1")
docs=("readme.txt" "license.txt")
options=('nosrcpack')

slackdesc=\
(
#|-----handy-ruler------------------------------------------------------|
"unrar (RAR files extractor and viewer)"
"unrar is a freeware app made available by RARLAB"
)


build() {
	cd $startdir/src/

	sed -e '/CXXFLAGS=/d' -e '/LDFLAGS=/d' -i unrar/makefile # Use system build flags

	cp -a unrar libunrar
	export LDFLAGS+=' -pthread'
	make -C libunrar lib
	make -C unrar -j1

	# install binary
	cd unrar
	mkdir -p $startdir/pkg/usr/bin
	cp unrar $startdir/pkg/usr/bin/
	cd ../libunrar
	# install library
	mkdir -p $startdir/pkg/usr/lib$LIBDIRSUFFIX
	cp libunrar.so $startdir/pkg/usr/lib$LIBDIRSUFFIX/libunrar.so.$pkgver
	majorver=`echo $pkgver | cut -d'.' -f1`
	minorver=`echo $pkgver | cut -d'.' -f2`
	(
	 cd $startdir/pkg/usr/lib${LIBDIRSUFFIX}
	 ln -s libunrar.so.$pkgver libunrar.so
	 ln -s libunrar.so.$pkgver libunrar.so.$majorver
	 ln -s libunrar.so.$pkgver libunrar.so.$majorver.$minorver
	)
	# install header
	mkdir -p $startdir/pkg/usr/include/unrar/
	cp dll.hpp $startdir/pkg/usr/include/unrar/
	# install manpage
	mkdir -p $startdir/pkg/usr/man/man1
	cp $startdir/src/unrar.1 $startdir/pkg/usr/man/man1/
}